'Abruf historischer Performance-Daten über ARD-Börse:
'Nach dem Kopieren der Funktion in ein VBA-Modul einer Excel-Datei (VBA-Project öffnen mit Alt+F11), kann die Funktion in jede beliebige Zelle wie folgt eingetragen werden:
'Beispiel:  =ardPerf(C3;"6M")
'Die Funktion benötigt zwei Parameter: ISIN und Zeitparameter. Im Beispiel steht in Zelle C3 die ISIN des Wertpapiers, Parameter 2 gibt den gewünschten Performance-Zeitraum für den Abruf an.
'Beides ist möglich: Angabe einer Zellposition, oder direkte Angabe des Parameters (in Anführungszeichen!) in der Funktion.
'Gültige Parameter-Werte für die Performance-Angabe sind: 1W, 1M, 3M, 6M, 1J, 3J, 5J, 10J

Public Function ardPerf(Isin As String, Perf As String) As Double
Dim Adresse As String
Dim KursString As String
Dim InfoBoxSplit As Integer
Dim IdSplit As Integer
Dim XML
On Error GoTo Fehler
Adresse = "https://kurse.boerse.ard.de/ard/kurse_einzelkurs_suche.htn?suchbegriff="
Set XML = CreateObject("MSXML2.ServerXMLHTTP")
XML.Open "GET", Adresse & Isin, False
XML.send
KursString = XML.responsetext
KursString = Split(KursString, "<h2>Performance")(1)
If Perf = "1W" Or Perf = "6M" Or Perf = "5J" Then InfoBoxSplit = 1
If Perf = "1M" Or Perf = "1J" Or Perf = "10J" Then InfoBoxSplit = 2
If Perf = "3M" Or Perf = "3J" Then InfoBoxSplit = 3
If Perf = "1W" Or Perf = "1M" Or Perf = "3M" Then IdSplit = 1
If Perf = "6M" Or Perf = "1J" Or Perf = "3J" Then IdSplit = 2
If Perf = "5J" Or Perf = "10J" Then IdSplit = 3
KursString = Split(KursString, "div class=")(InfoBoxSplit)
KursString = Split(KursString, "th id")(IdSplit)
KursString = Split(KursString, "strong>")(3)
KursString = Left(KursString, InStr(KursString, "%") - 1)
ardPerf = CDbl(KursString)
Set XML = Nothing
Exit Function
Fehler:
    ardPerf = 0
    Set XML = Nothing
End Function